A few notes on logging data to SD card.

You could use an openLog logger, which is a serial logger that attaches to whatever serial device you want. Here are some instructions on its use. You could also use other dataloggers like the uLog or the logomatic.

You could use the Arduino SD library (new as of version 0022) in conjunction with any SD card module, like these:

The SD library includes some code examples that work well for datalogging. Here is one for reference: 

/*
  SD card datalogger

 This example shows how to log data from three analog sensors 
 to an SD card using the SD library.

 The circuit:
 * analog sensors on analog ins 0, 1, and 2
 * SD card attached to SPI bus as follows:
 ** MOSI - pin 11
 ** MISO - pin 12
 ** CLK - pin 13
 ** CS - pin 4

 created  24 Nov 2010
 updated 2 Dec 2010
 by Tom Igoe

 This example code is in the public domain.

 */

#include <SD.h>

// On the Ethernet Shield, CS is pin 4. Note that even if it's not
// used as the CS pin, the hardware CS pin (10 on most Arduino boards,
// 53 on the Mega) must be left as an output or the SD library
// functions will not work.
const int chipSelect = 4;

void setup()
{
  Serial.begin(9600);
  Serial.print("Initializing SD card...");
  // make sure that the default chip select pin is set to
  // output, even if you don't use it:
  pinMode(10, OUTPUT);

  // see if the card is present and can be initialized:
  if (!SD.begin(chipSelect)) {
    Serial.println("Card failed, or not present");
    // don't do anything more:
    return;
  }
  Serial.println("card initialized.");
}

void loop()
{
  // make a string for assembling the data to log:
  String dataString = "";

  // read three sensors and append to the string:
  for (int analogPin = 0; analogPin < 3; analogPin++) {
    int sensor = analogRead(analogPin);
    dataString += String(sensor);
    if (analogPin < 2) {
      dataString += ","; 
    }
  }

  // open the file. note that only one file can be open at a time,
  // so you have to close this one before opening another.
  File dataFile = SD.open("datalog.txt", FILE_WRITE);

  // if the file is available, write to it:
  if (dataFile) {
    dataFile.println(dataString);
    dataFile.close();
    // print to the serial port too:
    Serial.println(dataString);
  }  
  // if the file isn't open, pop up an error:
  else {
    Serial.println("error opening datalog.txt");
  } 
}

Here's another example that logs an accelerometer attached to the analog pins: 

/*
  SD card datalogger

 This example shows how to log data from an ADXLaccelerometer 
 to an SD card using the SD library.

 The circuit:
 * Accelerometer:
 ** Power: pin A4
 ** GND: pin A0
 ** x: pin A3
 ** y: pin A2
 ** z: pin A1
 * SD card attached to SPI bus as follows:
 ** MOSI - pin 11
 ** MISO - pin 12
 ** CLK - pin 13
 ** CS - pin 8

 created  24 Nov 2010
 updated 1 Mar 2011
 by Tom Igoe

 This example code is in the public domain.

 */

#include <SD.h>

// On the Ethernet Shield, CS is pin 4. Note that even if it's not
// used as the CS pin, the hardware CS pin (10 on most Arduino boards,
// 53 on the Mega) must be left as an output or the SD library
// functions will not work.

const int chipSelect = 8;    // using SparkFun SD shield
const int accPower = A4;
const int accGnd = A0;
const int xAxis = A3;
const int yAxis = A2;
const int zAxis = A1;

void setup()
{
  Serial.begin(9600);
  Serial.print("Initializing SD card...");
  // make sure that the default chip select pin is set to
  // output, even if you don't use it:
  pinMode(10, OUTPUT);
  // use two pins to power the accelerometer
  pinMode(accPower, OUTPUT); 
  pinMode(accGnd, OUTPUT);
  digitalWrite(accGnd, LOW);
  digitalWrite(accPower, HIGH);

  // see if the card is present and can be initialized:
  if (!SD.begin(chipSelect)) {
    Serial.println("Card failed, or not present");
    // don't do anything more:
    return;
  }
  Serial.println("card initialized.");
}

void loop()
{
  // make a string for assembling the data to log:
  String dataString = "";

  // read three sensors and append to the string:

    int sensor = analogRead(xAxis);
    dataString += String(sensor);
    dataString += ",";
   delay(5);
     sensor = analogRead(yAxis);
    dataString += String(sensor);
    dataString += ",";
    delay(5);
     sensor = analogRead(zAxis);
    dataString += String(sensor);


  // open the file. note that only one file can be open at a time,
  // so you have to close this one before opening another.
  File dataFile = SD.open("datalog.csv", FILE_WRITE);

  // if the file is available, write to it:
  if (dataFile) {
    dataFile.println(dataString);
    dataFile.close();
    // print to the serial port too:
    Serial.println(dataString);
  }  
  // if the file isn't open, pop up an error:
  else {
    Serial.println("error opening datalog.txt");
  } 
}