However, in this case, once we write the text, the interaction never changes. We can simply add another button that clears the text:

// Put some text in text box when submit is clicked
function submitData(event:Event):void
{ // Put some text into the textContents text field
  textContents.text = "Here is some text.  What a lousy example.";
  
  // You can also append
  textContents.text += "\n\nSomebody please tell Red to find a new DWD teacher.";
  
  textContents.text += "\n\nThanks.";
};

function resetData(event:Event):void
{ // Clear the text field
  textContents.text = "";
};

mySubmit.addEventListener("click", submitData);
myReset.addEventListener("click", resetData);

Flash/PHP Interaction - The PHP Side   [top]
Flash and PHP communicate through name-value pairs that they each send to each other. This is similar to how an HTML form sends variables to PHP. In all cases, the values in these pairs are URL-encoded. Fortunately, we have a built PHP function which can take of this for us, urlencode(), which we can call in our PHP scripts as follows:

# Here is a data value to be sent to PHP
$phpData = "This is a value to be obtained in Flash";

# We need to URL encode the data for HTTP transport
$phpData = urlencode($phpData);

# We are now going to send one variable to Flash.  The name
#  of the var in Flash will be "serverData" and it will contain
#  the contents of the PHP var $phpData

print "serverData=$phpData";

serverData=This+is+a+value+to+be+obtained+in+Flash

Flash/PHP Interaction - The Flash Side   [top]
The main object used for client-server communication in Flash is the URLLoader object, which has set properties and methods for communicating with a remote web server. To specify a URL of interest, one creates a URLRequest object, and if there are name-value pairs to be sent to this URL (as in a GET or POST operation), a URLVariables object is used to define this data. The variables object is attached to the request object, and then the request object is used an argument to the URLLoader object. Thus, the basic flow of receiving data from a PHP script in Actionscript goes something like this:

import flash.net.*;

// Define the basic web path to our PHP script
var serverScript = "http://itp.nyu.edu/~netId/dwd/script.php";

var request:URLRequest = new URLRequest(serverScript);
var loader:URLLoader = new URLLoader();
var sent_vars:URLVariables = new URLVariables();

sent_vars.id = 56; // This is like calling: script.php?id=56

request.method = URLRequestMethod.GET;
request.data = sent_vars;

loader.addEventListener(Event.COMPLETE, onLoaded);

loader.load(request);

function onLoaded(event:Event):void
{
  // Create vars from the data returned in loader.data
  //  and put contents of serverData into the textContents text field
  var received_vars:URLVariables = new URLVariables(loader.data)
  textContents.text = received_vars.serverData;
}

To specify the data to be submitted, we can create a new instance of a URLVariables object, assign properties and values to it, and this data will be sent to our PHP script as name-value pairs, just as an HTML form might. Also, you don't need to URL encode your data like in PHP because Flash takes care of this for us. When this data arrives in PHP, it arrives as name-value pairs just like our HTML form submissions. The format is exactly the same.

When the data returns from the PHP script and is received in Flash, the onLoaded function is automatically called, and the data is in the "data" property of the URLLoader object. We can then use the URLVariables object to take the url-encoded string of name-value pairs returned by PHP and parse it into an object where the name becomes a property of the object and its value is the value in the name-value pair.

Flash Security Note Regarding Domains   [top]
Make sure the URL of the PHP script embedded in your movie has the same domain of the web page that contains your movie. In your movie, if you define the PHP script that you will use to be:

// Define PHP script to be called
serverScript = "http://stage.itp.tsoa.nyu.edu/~netId/dwd/submitSite.php";

http://stage.itp.tsoa.nyu.edu/~netId/dwd/site.html

// Define PHP script to be called
serverScript = "http://itp.nyu.edu/~netId/dwd/yourScript.php";
View at: http://itp.nyu.edu/~netId/dwd/PageContainingMovie.html

---

// Define PHP script to be called
serverScript = "http://stage.itp.nyu.edu/~netId/dwd/yourScript.php";
View at: http://stage.itp.nyu.edu/~netId/dwd/PageContainingMovie.html

Flash/PHP Example Movies   [top]
So let's look at some different ways we can interface Flash, PHP, and MySQL. In this first example, when the submit button is pressed in Flash, we use the URLLoader.load() method to call a PHP script on the server. This script gets all rows of our instruments table in the database, puts it in one variable called serverData and send it to Flash.

In this next example, we do pretty much the same thing except that we call the load() method at the beginning of our movie such that we don't have to press a button to initiate the request.

A common method for pulling data from a remote server is having Flash "poll" the database, meaning that it should check the contents of the DB continuously at some set interval. In this case, we simply use the Timer object built into Flash to define what will happen and with what frequency:

// Set the timer to make a request every 5 sec, looping inifinitely
var myTimer:Timer = new Timer(5000);
myTimer.addEventListener(TimerEvent.TIMER, refreshContents);
myTimer.start();

// Define function that will be called continuously
function refreshContents(event:TimerEvent):void
{ //  Simply call our PHP script to refresh text field with table contents
  loader.load(request);
}

The data in this text field is now tied to the live database. If we should happen to change it, then it will dynamically change with it. This next example provides us with the ability to "enable" and "disable" certain entries in our instruments DB table. In this case, we enter the ID of the row we want to change in the table, and we then either enable or disable it in our listing. Flash collects the value of the ID and whether the command is to enable or disable, sticks them in our URLVariables object, and then makes the call to PHP using the load() method of the URLLoader object. PHP makes the requested changes to the DB, then gets the new listing, and sends it back to Flash. When Flash receives it, it takes the listing and sticks it in the text field.

// Enable display of instrument when enable button is pressed
function enableItem(event:Event):void
{ 
  var sent_vars:URLVariables = new URLVariables();
  
  // Create cmd property and set it to "enable"
  sent_vars.cmd = "enable";
  
  // Get the ID of the row to affect which is in the textID widget
  sent_vars.id = textId.text;
  
  // Send it to the server using the GET method and wait for response
  var request:URLRequest = new URLRequest(serverScript);
   request.data = sent_vars;
  request.method = URLRequestMethod.GET;
  
  loader.load(request);
  
  request = null;
  sent_vars = null;
};

// Disable display of instrument when enable button is pressed
function disableItem(event:Event):void
{
  var sent_vars:URLVariables = new URLVariables();
  
  // Create cmd property and set it to "disable"
  sent_vars.cmd = "disable";
  
  // Get the ID of the row to affect which is in the textID widget
  sent_vars.id = textId.text;
  
  // Send it to the server using the GET method and wait for response
  var request:URLRequest = new URLRequest(serverScript);
   request.data = sent_vars;
  request.method = URLRequestMethod.GET;
  
  loader.load(request);
  
  request = null;
  sent_vars = null;
};

loader.addEventListener(Event.COMPLETE, onLoaded);
myEnable.addEventListener("click", enableItem);
myDisable.addEventListener("click", disableItem);

Favorite Sites Submission - Revisited   [top]
Now let's see how we can revamp the site submission portion of our favorite sites demo from a previous class. On the PHP side, the code is pretty much the same as it was in our previous version except that we don't need to format any of the visual stuff - since we are using Flash for our interface.

# Get the values from the widgets and trim whitespace
$title = trim($textTitleValue);
$url = trim($textUrlValue);
$desc = trim($textDescValue);

# Now check each widget.  Title widget is checked first to see if blank
if (empty($title))
{ # If blank, set general error flag, title error flag, and general error message
  $hasErrors = 1;
  $noTitle = 1;
  $statusMsg = "There were errors in your site submission.";
}

# Url widget is checked first to see if blank or default
if (empty($url) || $url=="http://")
{ # If blank, set general error flag, url error flag, and general error message
  $hasErrors = 1;
  $noUrl = 1;
  $statusMsg = "There were errors in your site submission.";
}

# Description widget is checked first to see if blank
if (empty($desc))
{ # If blank, set general error flag, desc error flag, and general error message
  $hasErrors = 1;
  $noDesc = 1;
  $statusMsg = "There were errors in your site submission.";
}

# If we had no errors, we can put it in the database
if (!$hasErrors)
{ # This is a good submission, so escape any single quotes in the text values
  $titleDB =  str_replace("'", "''", $title);
  $urlDB =  str_replace("'", "''", $url);
  $descDB =  str_replace("'", "''", $desc);
  
  # Create the SQL query
  $SqlStatement = "INSERT INTO class05_table2 (title,url,description)
    VALUES ('$titleDB','$urlDB','$descDB') ";

  # Run the query on the database through the connection
  $result = mysql_query($SqlStatement,$connection);
  
  $statusMsg = "Thank you for your site submission!";
}

$statusMsg = urlencode($statusMsg);

# Tell Flash what type of content to expect
header("Content-type: text/html");

# Send it to Flash
print "hasErrors=$hasErrors&statusMsg=$statusMsg";

// Enable display of instrument when enable button is pressed
function submitItem(event:Event):void
{ 
  var sent_vars:URLVariables = new URLVariables();
  
  sent_vars.siteName = siteName.text; // Get value of name widget
  sent_vars.siteUrl = siteUrl.text; // Get value of URL widget
  sent_vars.siteDesc = siteDesc.text; // Get value of description widget
  
  // Accumulate the vars in a string just for show, and show it
  textSend.text = sent_vars.toString(); // This is text field under "Sent Text"
  
  // Send it to the server using the POST method and wait for response
  var request:URLRequest = new URLRequest(serverScript);
   request.data = sent_vars;
  request.method = URLRequestMethod.POST;
  
  loader.load(request);
  
  request = null;
  sent_vars = null;
};

function onLoaded(event:Event):void
{
  textReturn.text = loader.data;
  
  // Create vars from the data returned in loader.data
  //  and parse the returned vars
  var received_vars:URLVariables = new URLVariables(loader.data)
  
  // Show the status that was returned.  Our PHP script sends:
  // result: 0=OK, 1=problem
  // status: string
  
  // If there was a status message, then show it
  if (received_vars.statusMsg.length>0)
    textStatus.text = received_vars.statusMsg;

  // If it was successful, then clear the widgets
  if (received_vars.hasErrors==0)
  { siteName.text = "";
    siteUrl.text = "http://";
    siteDesc.text = "";
  }
  
  received_vars = null;
  loader.data = null;
}

Flash, XML, and Dynamic Widget Population   [top]
In the same way that we could use PHP to dynamically populate dropdowns or checkboxes in HTML forms using data from our DB, we can do the same thing in Flash. Receiving lists of data in Flash as name-value pairs is OK, but somewhat cumbersome to parse, so we can use another format to receive the data that we now know quite well: XML. Flash has dedicated XML support, such that receiving XML from the server instead of name-value pairs, and parsing this data is performed with great ease:

import flash.net.*;

var myXML:XML = new XML(); // Have an XML object ready to go

// Define the basic web path to our PHP script
var serverScript = "http://itp.nyu.edu/~netId/dwd/script.php"; 
var request:URLRequest = new URLRequest(serverScript); 
var loader:URLLoader = new URLLoader(request);

loader.addEventListener("complete", xmlLoaded);

// Make the request
loader.load(request);

request = null;
 
function xmlLoaded(event:Event):void 
{ 
  myXML = XML(loader.data); 

  mySelect.removeAll();
  mySelect.addItem({label:"-- Select --", id:0}); 
  
  for (var i:String in myXML.item) 
  { 
    // trace(i + ": " + myXML.item.id[i] + ": " + myXML.item.name[i]);
    mySelect.addItem({label:myXML.item.name[i], id:myXML.item.id[i]});
  }
}

For the other XML format we used for AJAX in class 10, we can parse attributes in a similar manner, which we can use to populate our favorite sites inside a Flash combo box:

function xmlLoaded(event:Event):void 
{ 
  myXML = XML(loader.data);

  mySelect.removeAll();
  mySelect.addItem({label:"-- Select --", id:0}); 
  
  for (var i:String in myXML.o) 
  { 
    //trace(i + ": " + myXML.o.@id[i] + ": " + myXML.o.@title[i]);
    mySelect.addItem({label: myXML.o.@title[i], id: myXML.o.@id[i]});
  }
}

Flash and JSON   [top]
As part of the Adobe corelib project, a JSON ActionScript library is now available to provide JSON support in Flash. Using this library, we can easily load the data from our JSON web service that we created last week, decode it, and then use it to create a combo box containing our favorite sites:

import com.adobe.serialization.json.JSON;

...

function jsonLoaded(event:Event):void 
{ 
  var sites:Array = JSON.decode(loader.data);

  mySelect.removeAll();
  mySelect.addItem({label:"-- Select --", id:0});
  
  for (var key:Object in sites)
  {
    trace(sites[key].id + ": " + sites[key].title);
    mySelect.addItem({label: sites[key].title, id: sites[key].id});
  }
}

In order for Flash to be able to find any ActionScript libraries not included with the main distribution, we can put our libraries on our local hard drive in a folder of our choosing, and then include this folder in the settings for our source path in the settings under File > Publish Settings.

Introduction to Amazon Web Services (AWS)   [top]

Some of the most common web services in use today are the suite of tools provided by Amazon, known as Amazon Web Services (AWS). The ones we'll cover today are Amazon Simple Storage (S3): their service for online storage and static file serving, and SimpleDB: their service for providing basic database functionality.