class Tree
{
  ArrayList tree = new ArrayList();
  float rootx;
  float rooty;
  float rootangle;
  float branchsize;
  int maxL;
  
    
  Tree(float rx_, float ry_, float ra_, float bs_, int mL)
  {
    rootx=rx_;
    rooty=ry_;
    rootangle=ra_;
    branchsize=bs_;
    maxL=mL;
    
    branch(-1, rootx, rooty, branchsize, rootangle, 1, maxL);
    childinfo();
  }


  void branch(int p, float rx, float ry, float d, float a, int L, int MAXL)
  {
    float nx, ny;
    int indexhold;
  
    if(L < MAXL)
    {
      //Calculate and draw branch
        nx=rx+d*cos(-1*radians(a));
        ny=ry+d*sin(-1*radians(a));
    
      //Add to Arraylist 
        indexhold=tree.size();
        tree.add(new Node(L, indexhold, p, rx, ry, a, d));
    
      //Recurse
        branch(indexhold, nx, ny, d*.7, a+random(10,25), L+1, MAXL);
        branch(indexhold, nx, ny, d*.7, a-random(10,25), L+1, MAXL);
    }
  }//END branch

  void regenerate()
  {
    tree.clear();
    branch(-1, rootx, rooty, branchsize, rootangle, 1, maxL);
    childinfo();
  }//END regenerate

  void childinfo()
  {
    for(int i=0; i<tree.size(); i++)
    {
      Node n= (Node) tree.get(i);    
      if(n.getPARENT() >= 0)
      {
        Node n2= (Node) tree.get(n.getPARENT());
        if(n2.getC1()==-1)
        {
          n2.setC1(n.getME());
        }
        else
        {
          n2.setC2(n.getME());
        }       
      }  
    }  
  }

  void render()
  {
    float x, y;
  
    stroke(255);
    
    for(int i=0; i<tree.size(); i++)
    {
      Node n= (Node) tree.get(i);
    
      x=n.getRX()+n.getD()*cos(-1*radians(n.getA()));
      y=n.getRY()+n.getD()*sin(-1*radians(n.getA()));
    
      line(n.getRX(), n.getRY(), x, y);
    
    }
  }//END render
 
  int pressed(int caughti, float x, float y)
  {
    //RETURN NUMBER OF ONE CAUGHT AND ONLY THAT CAN BE CAUGHT NEXT TIME?
    float initiala;
    float adiff;
    boolean onecaught=false;
    int caught=-1;
    
    for(int i=0; i<tree.size(); i++)
    {
      Node n= (Node) tree.get(i);
      if(n.contains(x,y) && onecaught==false &&(caughti==-1 || caughti==i))
      {
        onecaught=true;
        caught=i;
        initiala=n.getA();
        n.MoveToTarget(x,y);
        adiff=initiala-n.getA();
        if(n.getC1()!=-1)
        {
          Node nc= (Node) tree.get(n.getC1());
          nc.setA(nc.getA()-adiff);
          alterchildrenangle(nc, adiff);
        }
        if(n.getC2()!=-1)
        {
          Node nc= (Node) tree.get(n.getC2());
          nc.setA(nc.getA()-adiff);
          alterchildrenangle(nc, adiff);
        }
      }
    }
    return caught;
  }//END pressed
  
  void alterchildrenangle(Node parent, float adiff)
  {
        if(parent.getC1()!=-1)
        {
          Node nc= (Node) tree.get(parent.getC1());
          nc.setA(nc.getA()-adiff);
          alterchildrenangle(nc, adiff);
        }
        if(parent.getC2()!=-1)
        {
          Node nc= (Node) tree.get(parent.getC2());
          nc.setA(nc.getA()-adiff);
          alterchildrenangle(nc, adiff);
        } 
  }
  
  void swingtree(float angle)
  {
    Node n= (Node) tree.get(0);
    n.setA(angle);
    alterchildrenangle(n, angle);
  }

  void alter()
  {
    float x, y;
  
    for(int i=0; i<tree.size(); i++)
    {
      Node n= (Node) tree.get(i);
    
      if(n.getPARENT() >= 0)
      {
        Node n2= (Node) tree.get(n.getPARENT());
        n.setRX(n2.returnx());
        n.setRY(n2.returny());        
      }
    }
  }//END alter

   
  ///////////////////////////////////////////////////////////////////////////////
  //Node Control FUNCTIONS
  ///////////////////////////////////////////////////////////////////////////////
   void controltree(int arg, int shakepiece)
    {
      for(int i=0; i<tree.size(); i++)
      {
        if(arg==1)
          {regenerate();}
        else if(arg==2)
          {randomwalk(i);}
        else if(arg==3)
          {sway(i, shakepiece);}
        else if(arg==4)
          {shrink(i);}
        else if(arg==5)
          {explode(i);}
        else if(arg==6)
          {angleshake(i);}
        else if(arg==7)
          {levelshake(i);}
      }
    }

    void randomwalk(int i)
    {
        Node n= (Node) tree.get(i);
        n.setA(n.getA()+random(-5,5));
    }//END randomwalk
  
    void explode(int i)
    {
        Node n= (Node) tree.get(i);    
        n.setPARENT(int(random(0,tree.size())));
    }//END explode
  
    void shrink(int i)
    {
        Node n= (Node) tree.get(i);      
        n.setA(n.getA()+random(-1,1));
        //if(n.getME()%3 ==2)
        if(n.getME()%3==0)
        {
          n.setD(n.getD()*random(.70,1.08));// Changing these makes tree shrink or grow
          //n.setD(n.getD()*random(.95,1.05)+3*sin(radians(millis())));// Changing these makes tree shrink or grow
        }
    }//END shrink()
  
   void sway(int i, int shakepiece)//NEEDS TO BE A SWAY THAT DEALS WITH CHILDREN TOO
   {
        Node n= (Node) tree.get(i);
        if(n.getLEVEL()==shakepiece)
        {
          n.setA(n.getA()+random(-5*float(n.getLEVEL()),float(n.getLEVEL())));
          //AND OR
          //n.setA(n.getA()+20/float(n.getLEVEL())*sin(radians(millis())));
        }
    }//END sway()
 
    void angleshake(int i)
    {
        Node n= (Node) tree.get(i);
        if(n.getA()>90)
        {
          n.setA(n.getA()+random(-5,5));
        }
    }//END angleshake()
 
    void levelshake(int i)
    {
        Node n= (Node) tree.get(i);
        if(n.getLEVEL()>4)
        {
          n.setA(n.getA()+random(-5,5));
        }
    }//END levelshake()
 

  
}//END Tree