class Tree
{
  ArrayList tree = new ArrayList();
  float rootx;
  float rooty;
  float rootangle;
  float branchsize;
  int maxL;
  
///////////////////////////////////////////////////////////////////////////////////////
//GENERATE + RENDER FUNCTIONS
///////////////////////////////////////////////////////////////////////////////////////    
  Tree(float rx_, float ry_, float ra_, float bs_, int mL)
  {
    rootx=rx_;
    rooty=ry_;
    rootangle=ra_;
    branchsize=bs_;
    maxL=mL;
    
    branch(-1, rootx, rooty, branchsize, rootangle, 1, maxL);
    childinfo();
  }

  void branch(int p, float rx, float ry, float d, float a, int L, int MAXL)
  {
    float nx, ny;
    int indexhold;
  
    if(L < MAXL)
    {
      //Calculate and draw branch
        nx=rx+d*cos(-1*radians(a));
        ny=ry+d*sin(-1*radians(a));
    
      //Add to Arraylist 
        indexhold=tree.size();
        tree.add(new Node(L, indexhold, p, rx, ry, a, d));
    
      //Recurse
        branch(indexhold, nx, ny, d*.7, a+random(10,25), L+1, MAXL);
        branch(indexhold, nx, ny, d*.7, a-random(10,25), L+1, MAXL);
    }
  }//END branch
  
  void singlebranch(int p, float rx, float ry, float d, float a, int L)
  {
    int indexhold;
     
    //Add to Arraylist 
      indexhold=tree.size();
      tree.add(new Node(L+1, indexhold, p, rx, ry, a, d));    
  }//END singlebranch

  void regenerate()
  {
    tree.clear();
    branch(-1, rootx, rooty, branchsize, rootangle, 1, maxL);
    childinfo();
  }//END regenerate
  
  void render()
  {
    float x, y;  
    stroke(255);   
    for(int i=0; i<tree.size(); i++)
    {
      Node n= (Node) tree.get(i);    
      x=n.getRX()+n.getD()*cos(-1*radians(n.getA()));
      y=n.getRY()+n.getD()*sin(-1*radians(n.getA()));    
      line(n.getRX(), n.getRY(), x, y);    
    }
  }//END render
 

/////////////////////////////////////////////////////////////////////////////////////////////
//UPDATE + CHILDREN FUNCTIONS
////////////////////////////////////////////////////////////////////////////////////////////
  void update()
  {
    float x, y;  
    for(int i=0; i<tree.size(); i++)
    {
      Node n= (Node) tree.get(i);    
      if(n.getPARENT() >= 0)
      {
        Node n2= (Node) tree.get(n.getPARENT());
        n.setRX(n2.returnx());
        n.setRY(n2.returny());        
      }
    }
    childinfo();
  }//END update
  
  void childinfo()
  {
    //println(tree.size());
    for(int i=0; i<tree.size(); i++)
    {
      Node n= (Node) tree.get(i);    
      if(n.getPARENT() >= 0 && n.getCONNECTED()==false)
      {
        Node n2= (Node) tree.get(n.getPARENT());
        n2.addCHILD(n.getME());
        n.setCONNECTED(true);            
      }  
    }  
  }

  void alterchildrenangle(Node parent, float adiff)
  {
       for(int i=0; i < parent.getCHILDSIZE(); i++)
       {
          Node nc= (Node) tree.get(parent.getCHILD(i));
          nc.setA(nc.getA()-adiff);
          alterchildrenangle(nc, adiff);        
       }
  }//END alterchilderangle

////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
//PRESSED FUNCTION
////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////  
  int pressed(int caughti, float x, float y)
  {
    float initiala;
    float adiff;
    boolean onecaught=false;
    int caught=-1;
    
    if(caughti == -1)
    {
      for(int i=0; i<tree.size(); i++)
      {
        Node n= (Node) tree.get(i);
        if(n.contains(x,y) && onecaught==false)
        {
          onecaught=true;
          caught=i;
        }
       }
     }
     else if(caughti != -1)
     {
        caught=caughti;        
        Node n= (Node) tree.get(caughti);
        initiala=n.getA();
        n.MoveToTarget(x,y);
        adiff=initiala-n.getA();        
        alterchildrenangle(n, adiff);
     }
    return caught;
  }//END pressed
  
   int pressedadd(int caughtin, float x, float y)
  {
    float initiala;
    float adiff;
    boolean onecaught=false;
    int caught=-1;
    
    if(caughtin == -1)
    {
      for(int i=0; i<tree.size(); i++)
      {
        Node n= (Node) tree.get(i);
        if(n.contains(x,y) && onecaught==false)
        {
          onecaught=true;
          caught=i;
        }
       }
     }
     else if(caughtin == -10)//meaning add
     {
        caught=caughtin;        
        Node n= (Node) tree.get(caughtin);
        initiala=n.getA();
        n.MoveToTarget(x,y);
        adiff=initiala-n.getA();        
        alterchildrenangle(n, adiff);
     }
    return caught;
  }//END pressed
  
  void addbranch(int parenti, float x, float y)
  {
    float nx, ny, d, a;
    Node n= (Node) tree.get(parenti); 
    //Calculate new root
        nx=n.getRX()+n.getD()*cos(-1*radians(n.getA()));
        ny=n.getRY()+n.getD()*sin(-1*radians(n.getA()));
        d=dist(nx,ny,x,y);
        a=degrees(atan2(ny-y,x-nx));  
    //Add the branch
        singlebranch(n.getME(), nx, ny, d, a, n.getLEVEL());
  }
  
  int giveparent(float x, float y)
  {
    boolean onecaught=false;
    int caught=-1;
    for(int i=0; i<tree.size(); i++)
    {
        Node n= (Node) tree.get(i);
        if(n.contains(x,y) && onecaught==false)
        {
          onecaught=true;
          caught=i;
        }
     }
     return caught;
   }
   
   void deletebranch(int nodei)
   {
     Node n= (Node) tree.get(nodei);
     for(int i=n.getCHILDSIZE()-1; i > -1; i=i-1)//may have to go backwards
     {
       deletebranch(n.getCHILD(i));
     }
     moveback(nodei);
     
     tree.remove(nodei);
   }//END deletebranch
   
   void moveback(int nodei)
   {
     //HERE this is absurd but: we search the entire structure to reset anything above the target
     //we also delete any references to this index except for parent references since these will be
     //deleted anyways
     for(int i=0; i < tree.size(); i++)
     {
       Node n= (Node) tree.get(i);
       //remove and decrement any child references
         for(int j = n.getCHILDSIZE()-1; j > -1; j--)
         {
            if(n.getCHILD(j) > nodei)
            {
              n.setCHILD(j, n.getCHILD(j)-1);
            }
            if(n.getCHILD(j)==nodei)
            {
              n.removeCHILD(j);
              j--;//pretty sure this belongs here
            }     
         }
       //decrement any parent references
         if(n.getPARENT() > nodei)
         {
           n.setPARENT(n.getPARENT()-1);
         }
       //if i > nodei decrement self reference
       if(n.getME() > nodei)
         {
           n.setME(n.getME()-1);
         }
     }
   }//END moveback
   
  ///////////////////////////////////////////////////////////////////////////////
  //Node Control FUNCTIONS
  ///////////////////////////////////////////////////////////////////////////////
   void controltree(int arg, int shakepiece)
    {
      for(int i=0; i<tree.size(); i++)
      {
        if(arg==1)
          {regenerate();}
        else if(arg==2)
          {randomwalk(i);}
        else if(arg==3)
          {sway(i, shakepiece);}
        else if(arg==4)
          {shrink(i);}
        else if(arg==5)
          {explode(i);}
        else if(arg==6)
          {angleshake(i);}
        else if(arg==7)
          {levelshake(i);}
      }
    }

    void randomwalk(int i)
    {
        Node n= (Node) tree.get(i);
        n.setA(n.getA()+random(-5,5));
    }//END randomwalk
  
    void explode(int i)
    {
        Node n= (Node) tree.get(i);    
        n.setPARENT(int(random(0,tree.size())));
    }//END explode
  
    void shrink(int i)
    {
        Node n= (Node) tree.get(i);      
        n.setA(n.getA()+random(-1,1));
        //if(n.getME()%3 ==2)
        if(n.getME()%3==0)
        {
          n.setD(n.getD()*random(.70,1.08));// Changing these makes tree shrink or grow
          //n.setD(n.getD()*random(.95,1.05)+3*sin(radians(millis())));// Changing these makes tree shrink or grow
        }
    }//END shrink()
  
   void sway(int i, int shakepiece)//NEEDS TO BE A SWAY THAT DEALS WITH CHILDREN TOO
   {
        Node n= (Node) tree.get(i);
        if(n.getLEVEL()==shakepiece)
        {
          //n.setA(n.getA()+random(-5*float(n.getLEVEL()),float(n.getLEVEL())));
          //AND OR
          //n.setA(n.getA()+20/float(n.getLEVEL())*sin(radians(millis())));
        }
        n.setA(n.getA()+20/float(n.getLEVEL())*sin(radians(millis()/n.getLEVEL())));
    }//END sway()
 
    void angleshake(int i)
    {
        Node n= (Node) tree.get(i);
        if(n.getA()>90)
        {
          n.setA(n.getA()+random(-5,5));
        }
    }//END angleshake()
 
    void levelshake(int i)
    {
        Node n= (Node) tree.get(i);
        if(n.getLEVEL()>4)
        {
          n.setA(n.getA()+random(-5,5));
        }
    }//END levelshake()
 
    void swingtree(float angle)
    {
      Node n= (Node) tree.get(0);
      n.setA(angle);
      alterchildrenangle(n, angle);
    }
  
}//END Tree