'jleblanc 4.12.06
'serial out for debugging this
'send 19 byte payload
'Also sends out to LCD
'mod of code sent to me by leif
DEFINE OSC 20 'OSC MUST BE SET TO HS
'SETUP LCD
'This setup will tell PBP a 2-line LCD is connected in 4-bit
'mode with the data bus on the top 4 bits of PORTB, Register
'Select on PORTB.1, and Enable on PORTB.0.
'Data Bits go like: 3>B.7, 2>B.6, 1>B.5, 0>B.4
DEFINE LCD_DREG PORTB
' Set starting Data bit (0 or 4) if 4-bit bus
DEFINE LCD_DBIT 4
' Set LCD Register Select port
DEFINE LCD_RSREG PORTB
' Set LCD Register Select bit
DEFINE LCD_RSBIT 1
' Set LCD Enable port
DEFINE LCD_EREG PORTB
' Set LCD Enable bit
DEFINE LCD_EBIT 0
' Set LCD bus size (4 or 8 bits)
DEFINE LCD_BITS 4
' Set number of lines on LCD
DEFINE LCD_LINES 2
' Set command delay time in us
DEFINE LCD_COMMANDUS 2000
' Set data delay time in us
DEFINE LCD_DATAUS 50
'include modedefs.bas for shiftin and out modes
INCLUDE "modedefs.bas"
'***************************************************************************
'*VARIABLES
'***************************************************************************
'general purpose variables
i VAR BYTE
counter VAR BYTE
'pin definitions for comm w/ Laipec TRW-24G
RF_CE VAR PORTD.7 'yellow
RF_CS VAR PORTD.3 'dark green
RF_DR VAR PORTD.2 'blue
'channel 1 PIN definitions
RF_CLK1 VAR PORTD.1 'black
RF_DATA_In VAR PORTD.0 'light blue
RF_DATA_Out VAR PORTD.0
'I/O + Control PINS
switch VAR portc.4
receiveLED VAR portc.3
sendLED VAR portc.2
' THIS IS THE ADDRESS FOR THE MiRF v01
WhichAddress1 VAR BYTE 'Channel 1
WhichAddress2 VAR BYTE 'Channel 2
' DEFINE VARIABLES FOR SERIAL TO PC
inv9600 CON 16468 ' baudmode for serin2 and serout2: 9600 8-N-1 inverted
non9600 CON 84 ' baudmode for serin2 and serout2: 9600 8-N-1 non-inverted
'constants for RF configuration modes
CONRFRX VAR BYTE
CONRFTX VAR BYTE
'indicates state of current RF configuration - TX is 0, RX is 1
RFCurrentState VAR BIT
'hold data for RF message
RFDataArrayIN VAR BYTE[19]
RFDataArrayOUT VAR BYTE[19]
'hold data for RF configuration
RFConfigArray VAR BYTE[16]
'variables for each received or sent message
msgFromID VAR BYTE
msgToID VAR BYTE
'ID variables
me VAR BYTE 'ID that should be set to a unique number for each board
friend VAR BYTE
me = 1 'ID that should be set to a unique number for each board
friend = 2
'this variable in association with switch triggers a send
trigger VAR BIT
trigger=0
num_sent VAR BYTE
num_sent=0
'Display Array
DisplayArray VAR BYTE[48] '3 lines by 16 bytes
'***************************************************************************
'*END VARIABLES
'***************************************************************************
'***************************************************************************
'*BOOTUP + MAIN CODE
'***************************************************************************
BOOTUP:
WhichAddress1 =$BA 'These are things maybe to change????
WhichAddress2 =$BA
PORTA = %00000000;
TRISA = %00000001; ' 0 = Output, 1 = Input (A.1 is RxPC)
PORTB = %00000000;
TRISB = %01101010; ' 0 = Output, 1 = Input (C.1 is RF_DATA_In, C.3 is RF_DR)
'intialize RF module configuration
'constants to define receive/transmit modes at 2402 Mhz frequency
CONRFRX = $05
CONRFTX = $04
RFCurrentState = CONRFRX
GOSUB INITRFCONFIG
msgToID = 0 ' CHANGE THIS TO WHO SHOULD RECIEVE MESSAGE
msgFromID = me ' CHANGE THIS TO ID OF SENDER
'Clear Screen
LCDOUT $fe, 1
MAIN:
LOW RF_CS ' bring CS low before turning CE high - only one high at a time!
HIGH RF_CE ' bring CE high to bring RF into active mode
'if there's a message waiting in the RX buffer, read it
IF RF_DR = 1 THEN
INPUT RF_DATA_In 'This makes that pin an Input PIN
GOSUB RECEIVERF
ENDIF
'if we want to send out a message switch will be on
IF switch = 1 AND trigger = 1 THEN 'if the switch is closed send a message
msgToID = friend ' CHANGE THIS TO WHO SHOULD RECIEVE MESSAGE
'Send 3 times
num_sent=1
GOSUB SENDDATA ' goto the sendData function
PAUSE 50
num_sent=2
GOSUB SENDDATA ' goto the sendData function
PAUSE 50
num_sent=3
GOSUB SENDDATA ' goto the sendData function
PAUSE 50
'num_sent=num_sent+1
trigger=0
'num_sent=num_sent-1
ENDIF
'if switch is off then reset it
IF switch=0 THEN trigger=1
GOTO MAIN
'***************************************************************************
'*SUB PROGRAMS
'***************************************************************************
'RECEIVERF
'LOADARRAYS
'RUNDISPLAY
'SENDDATA
'SETRFCONFIG
'INITRFCONFIG
RECEIVERF:
INPUT RF_DATA_In 'Redudant? given we say this in main loop?
'power down RF front-end for current conservation
LOW RF_CE
'clock in data from RF-24G to PIC
FOR i=0 TO 18
'clock should follow data by at least 50nsec
''This basically sends out a clock signal
''SHIFTIN DataPin,ClockPin,Mode,[Var{\Bits}...]
SHIFTIN RF_DATA_In, RF_CLK1, MSBPRE, [RFDataArrayIN[i]\8]
NEXT
'send received data to PC for serial debugging
FOR i=0 TO 18
SEROUT2 PORTC.6, 16468, [RFDataArrayIN[i]] 'Non DEC
NEXT
SEROUT2 PORTC.6, 16468, [10, 13] 'Non DEC
'OUTPUT TO LCD
GOSUB LOADARRAYS
'power up RF front-end again
HIGH RF_CE
'Absorb the incoming Message
msgToID = RFDataArrayIN[0] 'the receiver is in msgToID
msgFromID = RFDataArrayIN[1] 'sender information in msgFromID
'Here we blink to acknowledge we have received the message
HIGH receiveLED:PAUSE 50:LOW receiveLED:PAUSE 50
HIGH receiveLED:PAUSE 50:LOW receiveLED:PAUSE 50
RETURN 'RECEIVERF
LOADARRAYS:
'Note array element [2] is the line number
'Load first Line
IF RFDataArrayIN[2]=1 THEN
'Load first part of array
FOR i=0 TO 15
DisplayArray[i]=RFDataArrayIN[i+3]
NEXT
ENDIF
'Load second Line
IF RFDataArrayIN[2]=2 THEN
'Load second part of array
FOR i=0 TO 15
DisplayArray[i+16]=RFDataArrayIN[i+3]
NEXT
ENDIF
'Load third Line + Display
IF RFDataArrayIN[2]=3 THEN
'Load third part of array
FOR i=0 TO 15
DisplayArray[i+32]=RFDataArrayIN[i+3]
NEXT
'Print the whole array
GOSUB RUNDISPLAY
ENDIF
RETURN'LOADARRAYS
RUNDISPLAY:
'Clear Screen
LCDOUT $fe, 1
'Print some message line 1
FOR i=0 TO 15
LCDOUT DisplayArray[i]
NEXT
'Move to second line
LCDOUT $fe, $C0
FOR i=16 TO 31
LCDOUT DisplayArray[i]
NEXT
'Move to third line
LCDOUT $fe, $90
FOR i=32 TO 47
LCDOUT DisplayArray[i]
NEXT
RETURN'RUNDISPLAY
SENDDATA:
'19 byte message
'Load the RF data out array with our message
RFDataArrayOUT[0] = msgToID
RFDataArrayOUT[1] = msgFromID
RFDataArrayOUT[2] = num_sent 'this is line number 1-3, here just the number of times we've sent
'This it the paragraph message
RFDataArrayOUT[3] = "0"'byteval'msgData1
RFDataArrayOUT[4] = "1"'msgData2
RFDataArrayOUT[5] = "2"'msgData2
RFDataArrayOUT[6] = "3"'msgData2
RFDataArrayOUT[7] = "4"'msgData2
RFDataArrayOUT[8] = "5"'msgData2
RFDataArrayOUT[9] = "6"'msgData2
RFDataArrayOUT[10] = "7"'msgData2
RFDataArrayOUT[11] = "8"'msgData2
RFDataArrayOUT[12] = "9"'msgData2
RFDataArrayOUT[13] = "A"'msgData2
RFDataArrayOUT[14] = num_sent+48'msgData2
RFDataArrayOUT[15] = "C"'msgData2
RFDataArrayOUT[16] = "D"'msgData2
RFDataArrayOUT[17] = "E"'msgData2
RFDataArrayOUT[18] = "F"'msgData2
'set RF to transmit mode...
RFCurrentState = CONRFTX
GOSUB setRFConfig
' for shockburst TX, the sum of RX address, payload, and CRC must be less than 256 bits long
' the chip then tacks on a preamble to this message, and the total msg is 266 bits
OUTPUT RF_DATA_Out 'Makes the pin an Output
'get back into active mode
HIGH RF_CE
'Need pause between CE high and DATA clock out
PAUSEUS 100
'clock out 5 byte RF address of recipient
FOR i = 8 TO 12
'clock out this byte
SHIFTOUT RF_DATA_Out, RF_CLK1, MSBFIRST, [RFConfigArray[i]\8]
NEXT
'clock out 19 bytes of data payload
FOR i = 0 TO 18
'clock out this byte
SHIFTOUT RF_DATA_Out, RF_CLK1, MSBFIRST, [RFDataArrayOUT[i]\8]
NEXT
'start shockburst transmission
LOW RF_CE
PAUSEUS 300
'flash LED to indicate that we transmitted
HIGH sendLED:PAUSE 50:LOW sendLED:PAUSE 50
HIGH sendLED:PAUSE 50:LOW sendLED:PAUSE 50
'afterward, set RF back to its default receive state
RFCurrentState = CONRFRX
GOSUB setRFConfig
RETURN'SENDATA
SETRFCONFIG: ' THIS IS USED TO SWITCH BETWEEN RECIEVE AND TRANSMIT MODES
'during configuration of the transmitter, we need RF_DATA as an output
OUTPUT RF_DATA_Out
'set chip to configure mode (CE low, CS high)
LOW RF_CE
HIGH RF_CS
'pause between CS high and DATA clockout
PAUSEUS 100
'RFCurrentState indicates 2402 Mhz frequency and either RX or TX state
'clock out new configuration data from PIC to RF-24G
SHIFTOUT RF_DATA_Out, RF_CLK1, MSBFIRST, [RFCurrentState\8]
'configuration set on falling edge of CS
LOW RF_CS
LOW RF_CE
'for consistency with the rx, stick this here
INPUT RF_DR
'flash the LED on B6 to indicate that we configured
'high DEBUG_LED1
' pause 250
'low DEBUG_LED1
RETURN'SETRFCONFIG
INITRFCONFIG:
'configuration is a 144 bit word
'must be clocked in MSB first
'bit map
'143:120 - reserved for testing
'119:112 - length of data payload section RX channel 2
'111-104 - length of data payload section RX channel 1
'103:64 - up to 5 byte address for RX channel 2
'63:24 - up to 5 byte address for RX channel 1
'23:18 - number of address bits (both RX channels)
'17 - 8 or 16 bit CRC
'16 - enable on-chip CRCD generation/checking
'15 - enable two channel receive mode
'14 - communication mode (direct or shockburst)
'13 - RF data rate (1Mbps requires 16Mhz crystal)
'12:10 - crystal frequency
'9:8 - RF output power
'7:1 - frequency channel
'0 - RX or TX operation
'setup RFConfigArray with config bytes, see datasheet for default configuration
'this array is backwards so we can clock from MSB to LSB by increasing the index
'Data bits 119-112: Max data width on channel 2 (excluding CRC and adrs)
RFConfigArray[1] = $98 'payloadSize, 19 BYTES (this is 19*8 for bits in hex)
'Data bits 111-104: Max data width on channel 1 (excluding CRC and adrs)
RFConfigArray[2] = $98 'payloadSize, 19 BYTES
'Data bits 103-64: Channel 2 address, 5 bytes (40 bits)
RFConfigArray[3] = WhichAddress2
RFConfigArray[4] = WhichAddress2
RFConfigArray[5] = WhichAddress2
RFConfigArray[6] = WhichAddress2
RFConfigArray[7] = WhichAddress2
'Data bits 63-24: Channel 1 address, 5 bytes (40 bits)
RFConfigArray[8] = WhichAddress1
RFConfigArray[9] = WhichAddress1
RFConfigArray[10] = WhichAddress1
RFConfigArray[11] = WhichAddress1
RFConfigArray[12] = WhichAddress1
'Data bits 23-16: Address width and CRC - 40 bit addr, 16 bit CRC, CRC enabled
RFConfigArray[13] = $A3
'Data bits 15-8: One Channel Receive, Shockburst Enabled, 250 kilobits, etc
RFConfigArray[14] = $4F
'Data bits 7-0: 2402 Mhz frequency, RX enabled/disabled (depending on RFCurrentState)
RFConfigArray[15] = RFCurrentState
'===================================================================
'During configuration of the transmitter, we need RF_DATA as an output
INPUT RF_DR
INPUT RF_DATA_In
OUTPUT RF_DATA_Out
'set chip to configure mode (CE low, CS high)
LOW RF_CE
HIGH RF_CS
'pause between CS high and DATA clockout
PAUSEUS 100
'clock out configuration bytes from PIC to RF-24G
FOR i = 1 TO 15
'set config one byte at a time from MSB to LSB
SHIFTOUT RF_DATA_Out, RF_CLK1, MSBFIRST, [RFConfigArray[i]\8]
NEXT
'configuration is set on the falling edge of CS, bring it low
LOW RF_CS
LOW RF_CE
'flash LED on pin B6 to debug that we configured
HIGH sendLED:PAUSE 250:LOW sendLED:PAUSE 250
HIGH receiveLED:PAUSE 250:LOW receiveLED:PAUSE 250
HIGH sendLED:PAUSE 250:LOW sendLED:PAUSE 250
HIGH receiveLED:PAUSE 250:LOW receiveLED:PAUSE 250
RETURN'INITRFCONFIG
'***************************************************************************
'*END SUB PROGRAMS
'***************************************************************************