// Weather

PFont f;

String weather = "";
String[] zips = {"10003","21209","90210","30008","07024"};
int temp;
int counter = 0;

void setup() {
  size(200,200);
  // Call our new getWeather function!
  getWeather(zips[counter]);
  f = loadFont("CopperplateGothic-Bold-48.vlw");
  println(temp);
  }
  
void draw() {
  background(255,0,0);
  textFont(f,15);
  fill(255);
  //Display all the stuff we want to display
  text(zips[counter],10,160);
  text(weather,10,90);
  text(temp,10,40);
  text("click to change zip.",10,180);
 
  //Draw a little thermometer based on the temperature
  noStroke();
  fill(255);
  rect(10,50,temp*2,20);
  
  }
  
void mousePressed() {
  // Increment the counter and get the weather at the next zip code
  counter = (counter +1) % zips.length;
  getWeather(zips[counter]);
  }
  
void getWeather(String zip) {
  // Get all the HTML/XML source code into an array of strings
  // (each line is one element in the array)
  String url = "http://xml.weather.yahoo.com/forecastrss?p=" + zip;
  String[] lines = loadStrings(url);
  
  String xml = join(lines, " ");  // Get rid of the array and make it one very long String
  
 // Searching for weather condition
 String lookfor = "<yweather:condition text=\"";
 String end = "\"";
 weather = giveMeTextBetween(xml,lookfor,end);
 
  // Searching for temperature
  lookfor = "temp=\"";
  temp = int(giveMeTextBetween(xml,lookfor,end));
  }
  
// A function that returns a substring between two substrings
String giveMeTextBetween(String s, String before, String after) {
  int start = s.indexOf(before);      // Find the index of the beginning tag
  if (start == -1) return "";   // If we don't find anything, send back a blank String
  start += before.length();  // Move to the end of the beginning tag
  int end = s.indexOf(after,start);   // Find the index of the end tag
  if (end == -1) return "";     // If we don't find anything, send back a blank String
  return s.substring(start,end);   // Return the text in between
  }